Probability density of sum of gamma and uniform

The probability density of the sum of gamma and uniform variables is the convolution of their densities, as it was for the sum of Gaussian and uniform variables, which we considered in a previous post. As before I'll define a simplifying unit boxcar function and a general boxcar to represent the uniform density.

matchdeclare (xx, numberp) $

tellsimp (U1(xx), if 0 <= xx and xx < 1 then 1 else 0) $

U(x, a, b) := 1/(b - a) * U1((x - a)/(b - a)) $

Let's let h be the density of a gamma variable, with parameters a and b.

h (x, a, b) := b^a / gamma(a) * x^(a - 1) * exp (-b*x);

⇒

$h(x,a,b):=\left(\frac{b^a}{\Gamma \left(a\right)}{x}^{a-1}\exp \left(\left(-b\right)x\right)\right)$

Here's the convolution integral. I'll quote the density functions to make the structure more obvious and therefore make further manipulation easier.

I : 'integrate ('h (r - s, a[1], b[1]) * 'U (s, a[2], b[2]), s, minf, r);

⇒

${\int }_{-\infty }^{r}h(r-s,a_1,b_1)U(s,a_2,b_2)ds$

As in a previous blog post, I'll define some simplification rules in order to manipulate the integral to the point that Maxima's built-in integrate function can handle it. There's a slightly obscure strategem in the definition of the second rule. yy_minus_xx is assigned before turning off the simplification flag, since it is important that the rule match the simplified form of y - x, which is internally represented as y + (-1)*x.

matchdeclare (xx, symbolp, [aa, bb], all) $

matchdeclare (ee, all) $

matchdeclare ([ll1, ll2], all) $

yy_minus_xx : yy - xx $

simp : false $

tellsimp

('integrate (ee * 'U(xx, aa, bb), xx, ll1, ll2),

1/(bb - aa) * 'integrate (ee, xx, max (ll1, aa), min (ll2, bb))) $

tellsimp

('integrate ('U(''yy_minus_xx, aa, bb)*ee, xx, ll1, ll2),

'integrate ('U(xx, yy - bb, yy - aa)*ee, xx, ll1, ll2)) $

simp : true $

Now let's allow Maxima to apply the rules we just defined. The effect of quote-quote is just as if we just typed in the value of I.

I1 : ''I;

⇒

$\frac{{\int }_{a_2}^{\min (b_2,r)}h(r-s,a_1,b_1)ds}{b_2-a_2}$

I originally defined the integral with h quoted in the integrand. Let's verbify it.

I2 : I, h;

⇒

$\frac{b_1^{a_1}{\int }_{a_2}^{\min (b_2,r)}{\left(r-s\right)}^{a_1-1}{e}^{-b_1\left(r-s\right)}ds}{\left(b_2-a_2\right)\Gamma \left(a_1\right)}$

I'll make a change of variables from r - s to u which simplifies the integrand somewhat.

I3 : changevar (I2, u - (r - s), u, s);

⇒

$-\frac{b_1^{a_1}{\int }_{r-a_2}^{r-\min (b_2,r)}{u}^{a_1-1}{e}^{-b_{1}u}du}{\left(b_2-a_2\right)\Gamma \left(a_1\right)}$

Now we're ready to evaluate the integral. I'll assert some inequalities to forestall questions from 'integrate'. These are all necessary conditions for the definition of the gamma and uniform density functions.

assume (a[1] > 0, b[1] > 0, b[2] > a[2]) $

assume (r > a[2]) $

assume (min (b[2], r) > a[2]) $

I4 : I3, nouns;

⇒

$-\frac{b_1^{a_1}\left(\frac{\Gamma (a_1,b_{1}r-b_1{a}_2)}{b_1^{a_1}}-\frac{\Gamma (a_1,b_{1}r-b_1\min (b_2,r))}{b_1^{a_1}}\right)}{\left(b_2-a_2\right)\Gamma \left(a_1\right)}$

Terrific, now we have computed the convolution symbolically. Note the gamma function, Γ(a), and the upper incomplete gamma function, Γ(a, z), in the result. We'll take a look at a specific example, as given by specific values for the parameters.

I5 : subst ([a[1] = 1/4, b[1] = 1/2, a[2] = 5, b[2] = 12], I4);

⇒

$-\frac{2^{\frac{1}{4}}\Gamma (\frac{1}{4},\frac{r}{2}-\frac{5}{2})-2^{\frac{1}{4}}\Gamma (\frac{1}{4},\frac{r}{2}-\frac{\min (12,r)}{2})}{72^{\frac{1}{4}}\Gamma \left(\frac{1}{4}\right)}$

Let's define a function which has those parameter values baked in, and plot it.

conv_symbolic (r) := ''I5 $

plot2d (conv_symbolic, [r, 0, 20]) $

It's interesting that the convolution function is asymmetric. I guess that's not surprising, since the gamma density is asymmetric too. Well, that's all for now.